平面圖樁號標註

平面圖樁號標註是平面圖的定線取完之後必經過程

生成流心的部分是透過設定取樣密度(流心連線距離)，去抓兩個邊界的中心點連線取得中心點，再將收集到的中心點連線而成。

圖中的定線(紅色線段)可能是AcadPolyline或者是AcadLWPolyline
兩者的差別僅在於Coordinates是否有Z值

大致上概念是將該多段線先任取兩點取得其"方位角"再用方位角+90度與方位角-90度取出橫斷面樁兩端點，再進行後續處理。

程式碼的概念都是幾何關係，滿滿的都是包括極坐標轉XY、方位角轉正角，XY轉方位角
有興趣者請參考以下程式碼~

UI介面：


圖面成果：

我比較偏愛這款(右樁標註+左樁標註+方向旗標)





程式碼：

'clsCL

Private CAD As New clsACAD
Private Math As New clsMath

Private arrLen() As Variant
Private arrLoc() As Variant
Private collCLPt As New Collection
Private CL As Object
Private BL As Object
Private pts As Variant
Private CO As Byte
Private totalLen As Double

Public w As Double
Public nowLoc As Double
Public IsLeftShow As Boolean
Public IsRightShow As Boolean
Public NeedBox As Boolean
Public NeedDir As Boolean
Public BLnext As Double

Const WIDTH_COE = 1.2

Private Sub Class_Initialize()

Set lay = CAD.acaddoc.Layers.Add("橫斷面樁")
lay.color = 4 'acCyan

Set lay = CAD.acaddoc.Layers.Add("中心樁")
lay.color = 1 'acRed

On Error Resume Next

CAD.acaddoc.Linetypes.Load "CENTER", "acad.lin"

lay.linetype = "CENTER"

End Sub

Sub CrossLine_Main()

Dim nextL As Double
Dim storeLen As Double

IsFirst = True

'Call getCenterLine(pts, CO, totalLen)
'Call getLoc(totalLen)

k = 1
nextL = arrLen(0)

For i = 0 To UBound(pts) - CO Step CO

    X0 = pts(i): Y0 = pts(i + 1)
    X1 = pts(i + CO): Y1 = pts(i + 1 + CO)

    ptLen = Sqr((X1 - X0) ^ 2 + (Y1 - Y0) ^ 2)  '兩點距

    fi = Math.getAz(X0, Y0, X1, Y1)
    
    If IsFirst Then
    
        MyLoc = Format(nowLoc + 0, "0K+000")
        Call DrawCrossLine(X0, Y0, fi, MyLoc)
        IsFirst = False
    
    End If
    
    sumLen = sumLen + ptLen

    If sumLen <= nextL Then storeLen = storeLen + ptLen '不夠用先存起來

    Do Until sumLen <= nextL
        
        moveL = nextL
        
        If storeLen <> 0 Then moveL = nextL - storeLen: storeLen = 0

        sumLen = sumLen - nextL

        If k <= UBound(arrLen) Then nextL = arrLen(k) '下一單距
        
        dx = Math.degcos(fi) * (moveL)
        dy = Math.degsin(fi) * (moveL)
        
        Xnow = X0 + dx: Ynow = Y0 + dy
        X0 = Xnow: Y0 = Ynow
        
        MyLoc = arrLoc(k - 1)
        
        Call DrawCrossLine(X0, Y0, fi, MyLoc)

        k = k + 1
    
    Loop

    storeLen = sumLen
    
Next

MyLoc = Format(nowLoc + totalLen, "0K+000")

Call DrawCrossLine(X1, Y1, fi, MyLoc)

End Sub

Sub getCenterLine() 'pts, CO, totalLen)

If CL Is Nothing Then
    
    Set sset = CAD.CreateSSET("CL")
    Set CL = sset(0)
    CL.Layer = "中心樁"
    
End If

pts = CL.Coordinates
totalLen = CL.Length
CO = 3
If TypeName(CL) = "IAcadLWPolyline" Then CO = 2

End Sub

Sub DrawCrossLine(ByVal X0 As Double, ByVal Y0 As Double, ByVal fi As Double, ByVal MyLoc As String)

CAD.acaddoc.ActiveLayer = CAD.acaddoc.Layers("橫斷面樁")

Dim spt(2) As Double
Dim ept(2) As Double

spt(0) = X0 + Math.degcos(fi + 90) * w
spt(1) = Y0 + Math.degsin(fi + 90) * w

ept(0) = X0 + Math.degcos(fi - 90) * w
ept(1) = Y0 + Math.degsin(fi - 90) * w

Set lineObj = CAD.AddLine(spt, ept)

If NeedDir Then

    Call DrawDirection(spt, fi, -w / 16, w / 10)
    Call DrawDirection(ept, fi, w / 16, w / 10)

End If

Call CAD.SetXdataToObj(lineObj, Replace(MyLoc, "K", ""))

If IsRightShow Then Call DrawCrossLoc(X0, Y0, MyLoc, fi, 90, 1)
If IsLeftShow Then Call DrawCrossLoc(X0, Y0, MyLoc, fi, -90, 3)

End Sub

Private Sub DrawDirection(dpt, fi, dx, dy)

Dim spt(2) As Double
Dim Tri As Object
Dim vertices(4 * 3 - 1) As Double

X = dpt(0): Y = dpt(1)

vertices(0) = X: vertices(1) = Y
vertices(3) = X: vertices(4) = Y + dy 'w / 5
vertices(6) = X + dx: vertices(7) = Y
vertices(9) = X: vertices(10) = Y

Set Tri = CAD.AddPolyLine(vertices)
Tri.rotate dpt, Math.deg2rad(-fi)

Call CAD.Hatch(Tri, 1, "SOLID")

End Sub

Private Sub DrawCrossLoc(X0, Y0, MyLoc, fi, ByVal rotangle As Double, ByVal alignmode As Byte)

Dim tept(2) As Double

tept(0) = X0 + Math.degcos(fi + rotangle) * w * WIDTH_COE
tept(1) = Y0 + Math.degsin(fi + rotangle) * w * WIDTH_COE

Set txtobj = CAD.AddMixText(MyLoc, tept, w / 5, alignmode)
If NeedBox Then Set boxobj = CAD.AddTextBox(txtobj)

txtobj.rotate tept, Math.deg2rad(-fi)
If NeedBox Then boxobj.rotate tept, Math.deg2rad(-fi)

End Sub

Sub getLoc() 'ByVal totalLen As Double)

Dim sumLen As Double
Dim c As Integer
IsAsk = True

Do While sumLen < totalLen

    If IsAsk = True Then
        nextLen = InputBox("起始樁號為 " & Format(0, "0+000") & vbNewLine & _
                            "結束樁號為 " & Format(nowLoc + totalLen, "0+000") & vbNewLine & _
                             "請輸入下一樁的單距，目前為" & Format(nowLoc + sumLen, "0+000"))
    End If
    
    If nextLen Like "*-" Then
        nextLen = Val(Left(nextLen, Len(nextLen) - 1)): IsAsk = False
    Else
        nextLen = Val(nextLen)
    End If

    sumLen = sumLen + nextLen
    
    ReDim Preserve arrLoc(c)
    ReDim Preserve arrLen(c)
    
    arrLen(c) = nextLen
    arrLoc(c) = Format(nowLoc + sumLen, "0K+000")
    
    c = c + 1

Loop

End Sub

Sub getLocXLS()

Dim collmyloc As New Collection

Set sht = Sheets("土方")

With sht

    lr = .Cells(Rows.Count, 1).End(xlUp).Row

    For r = 2 To lr

        collmyloc.Add Math.TranLoc(.Cells(r, 1))

    Next

End With

nowLoc = collmyloc(1)

For i = 1 To collmyloc.Count - 1

    ReDim Preserve arrLoc(i - 1)
    ReDim Preserve arrLen(i - 1)

    Interval = collmyloc(i + 1) - collmyloc(i)
    sumInterval = sumInterval + Interval

    arrLen(i - 1) = Interval
    arrLoc(i - 1) = Format(nowLoc + sumInterval, "0K+000")

Next
    
End Sub

Sub BorderLine_Main()

Dim nextL As Double
Dim storeLen As Double

IsFirst = True

Call getBorderLine(pts, CO, totalLen)

k = 1
nextL = BLnext

For i = 0 To UBound(pts) - CO Step CO

    X0 = pts(i): Y0 = pts(i + 1)
    X1 = pts(i + CO): Y1 = pts(i + 1 + CO)

    ptLen = Sqr((X1 - X0) ^ 2 + (Y1 - Y0) ^ 2)  '兩點距

    fi = Math.getAz(X0, Y0, X1, Y1)
    
    If IsFirst Then
    
        Call getCLpt(X0, Y0, fi): IsFirst = False
    
    End If
    
    sumLen = sumLen + ptLen

    If sumLen <= nextL Then storeLen = storeLen + ptLen '不夠用先存起來

    Do Until sumLen <= nextL
        
        moveL = nextL
        
        If storeLen <> 0 Then moveL = nextL - storeLen: storeLen = 0

        sumLen = sumLen - nextL

        'If k <= UBound(arrLen) Then nextL = arrLen(k) '下一單距
        
        dx = Math.degcos(fi) * (moveL)
        dy = Math.degsin(fi) * (moveL)
        
        Xnow = X0 + dx: Ynow = Y0 + dy
        X0 = Xnow: Y0 = Ynow
        
        Call getCLpt(X0, Y0, fi)

        k = k + 1
    
    Loop

    storeLen = sumLen
    
Next

MyLoc = Format(nowLoc + totalLen, "0K+000")

Call getCLpt(X1, Y1, fi)

End Sub

Sub getCLpt(ByVal X As Double, ByVal Y As Double, ByVal fi As Double)

Dim spt(2) As Double
Dim ept(2) As Double
Dim midpt(2) As Double

spt(0) = X + Math.degcos(fi + 90)
spt(1) = Y + Math.degsin(fi + 90)

ept(0) = X + Math.degcos(fi - 90)
ept(1) = Y + Math.degsin(fi - 90)

Set CrossLine = CAD.AddLine(spt, ept)

On Error Resume Next

retpt1 = CrossLine.IntersectWith(CL, acExtendThisEntity)
retpt2 = CrossLine.IntersectWith(BL, acExtendThisEntity)

midpt(0) = (retpt1(0) + retpt2(0)) / 2
midpt(1) = (retpt1(1) + retpt2(1)) / 2

If midpt(0) <> 0 Then collCLPt.Add midpt

CrossLine.Delete

End Sub

Private Sub getBorderLine(pts, CO, tl)

Set sset = CAD.CreateSSET("CL")
Set CL = sset(0)

pts = CL.Coordinates
tl = CL.Length
CO = 3
If TypeName(CL) = "IAcadLWPolyline" Then CO = 2

Set sset = CAD.CreateSSET("BL")
Set BL = sset(0)

End Sub

Sub DrawCenterLine()

Dim vertices() As Double
ReDim vertices(3 * collCLPt.Count - 1)

For i = 1 To collCLPt.Count

    pt = collCLPt.Item(i)
    
    vertices(3 * (i - 1)) = pt(0)
    vertices(3 * (i - 1) + 1) = pt(1)

Next

Set CL = CAD.AddPolyLine(vertices)

CL.Layer = "中心樁"

End Sub

留言

  1. 小小工程師2020年3月18日 凌晨2:33

    大大您好，冒昧打擾您了，小的對這平面圖樁號標註很有興趣，也嘗試用幼幼班程度的語法弄了UI介面，但過程一直出錯，有點挫折，不知道大大方便可以分享這程式嗎? 在此萬分感謝

    回覆刪除
  2. 小小工程師2020年3月19日 下午6:25

    麻煩您了，這是小的信箱 cruisewing@gmail.com

    回覆刪除
  3. 創聚2024年3月26日 晚上11:00

    你好，請問能否分享程式? 感激
    c194739@gmail.com

    回覆刪除

張貼留言

Popular Posts

Excel VBA @ 監造日報表、查驗表 -2

圖片
***如需施工日誌請參考 這裡 *** 20250106更新: 新的部落格連結 新版本20111214 已經更新!! 前言： 在經歷多次改版，發現使用的步驟還是有點多餘而且不夠自動化，此次將用物件類別模組的方式來修改Ver1.0留下尚可使用的程式碼，打造嶄新的監造日報表Ver2.0，輸出模式改為PDF，請搭配 PDFBinder 進行使用會比較方便。 準備文件： 以PCCES所編制並匯出成Excel之預算書報表 工程預算書中的數量計算表、土方計算表 監造日報表VBA使用手冊( 下載點我 ) 請開啟巨集並於login頁註冊後登入即可使用 圖一、Login頁面中點選註冊後跳至Google表單，填寫後即可以登入使用 參考文章： 專文1-PCCES處理到預算書 專文2-基本資料填寫 專文3-整個報表的靈魂 專文4-預定進度湊不到100%的解法  (20221204更新) 使用過程簡介： 1.  於工作表("Main")中填寫有關 工程名稱、 試體名稱(P.S.1) 、施工渠道名稱、進度資料等。 2.  於工作表("Budget")中點選"取得預算書"，修正為圖二所展示的內容。 圖二、取得預算書結果，如果需要整理準則，請參考設定準則的註解進行設定，並點選"重整準則" 3.  整理完成後並且更改為契約單價後，點選"匯出至報表"，資料會傳送至工作表("Main")，如下圖三所展示。 圖三、工作表("Main")中的報表資料，A~E欄為放置Step1 中的基本資料。 4.  於工作表("Records")中點選"填寫表單"，如圖四，即可進行一系列的資料紀錄，      為供應Diary及Check的基底資料。 圖四、施作項目來源是Main中的試體名稱與報表資料，如填寫資料有需要進行查驗，可以直接勾選(可複選) 5. 填寫完之後點選"傳送至Check"，再至工作表("Check")中點選"列印查驗"，     成果將輸出到該目錄下的查驗表Out...
Read more »

ExcelVBA@施工照片整理的應用範例

圖片
前言： 施工照片或者查驗照片對於許多工程人員來說，是個繁瑣的麻煩事。畢竟照片只是一張圖片，需要用人眼去判讀才有辦法了解內容是什麼，因為通常會有一張白板與工地現場進行合照，然而當撰寫白板的人寫字醜到不行時，會使人瘋狂。因此在施工照片的整理上，只要能解決 照片的資訊標示 與 報表位置自動貼附並調整大小 ，想必會讓各位有此類需求的工程人員節省許多時間。 相片的收集來源有以下方式 從相機的SD卡或手機連接USB直接進行下載，其檔案名稱通常為IMG_XXXX 或 DCIM_XXXX 。 透過LINE社群中建立相簿，並將同類屬性的照片丟進同一個相簿中，爾後再透過LINE電腦版將整本相簿進行下載，其檔案名稱通常為 LINE_ALBUM_相簿名稱_XXXX 。 上述兩種方式為筆者曾經使用過的方法，於資料夾檢視情況下僅有縮圖及沒有資訊標示的檔案名稱，需要雙擊展開大圖後才有辦法判讀該相片的用途，雖然上面有一張小白板的合照，但還是需要點開之後才有辦法了解內容是什麼，而【點開】並做【資訊標示】， 本身就是一件很麻煩的事 。 解決方案： 筆者的作法是將照片先整理至一個資料夾的底下，並透過LINE相簿在進行批次下載時指定其子資料夾名稱。之後便透過我所撰寫的【施工照片瀏覽及更名】的VBA小程式進行照片的資訊標示與報表輸出，詳細操作流程如下 點擊【取得資料夾】按鈕，選取已整理好的根資料夾位置。 點擊【貼上結果】按鈕，選取是否要在工作表上顯示縮圖及大小。 移動至工作表(Result)，若於工作表(Main)中有設定顯示大圖，則進入工作表(Result)中便會根據滑鼠選取的欄位顯示相對應的大圖資訊，並留有資訊標示欄位供使用者輸入做修改。 圖一、施工照片大圖資訊 有關施工照片資訊標示均輸入完畢之後，移動至工作表(Main)點擊【更換檔名】按鈕，以VBA可判讀的資訊標示的格式進行檔案名稱儲存，未來若有相對應的格式，系統會自動判讀並做預先設定，不用再輸入一次。 點擊【列印報表】按鈕，將會依照排序方法(時間或者項目)，依序將照片自動貼上於報表中並轉換成XLS或PDF， 製作成PDF才有辦法將檔案發布給其他人使用 ，如為XLS則會在自身電腦中並帶有照片原始檔的狀況下才能看到圖片。 圖三、施工照片報表輸出PDF模式。 圖三、施工照片報表輸出XLS。 若有施工照片需要的朋友們 施工照片VBA買斷版連結 *0313更...
Read more »

Excel表轉出至CAD

圖片
在進行施工設計時，常使用Excel來進行數據的運算，常見有： 主結構配筋的時候要試算鋼筋數量、長度、重量 → 鋼筋數量表 主結構重要數量核算 → 材料數量表 渠道使用明渠水理試算 → 水理因素表 當然需要的表格不僅有這些，還有拉力強度、彎距強度...等等的試算(在一些重要的結構物上)，但我也沒碰過故不清楚這部分。 在CAD中畫圖時，將Excel表轉至CAD檔方法有： 利用AutoCAD插入表格，然後導入Excel檔。 複製/貼上，將Excel要得區域複製，到AutoCAD中貼上。 利用第三方軟體，做AutoCAD與Excel橋接。 詳細圖片說明請參考 ：  營建的馬克與電腦 筆者認為第三方軟體也是需要花錢的，故寫了個VBA供大家參考使用： 下載連結：  ExcelToCAD_ConverceData.dvb 程式使用方法展示：       1.   輸入你要前往的工作表位置 ( 請輸入名稱索引 , 最前方的數字 ) ，按下 Enter          ※如果偵測到工作表的頁數超過一頁的話才會啟動詢問 2.  直接選擇你要轉換的連結區域後，按下 Enter 20190307更新: 上述的原始碼還是有一點寫太麻煩了，這次直接實作一個clsExcelToCAD物件並同時引用clsACAD物件，執行主要程序為ExportToCAD，偵測的內容是被框選到的儲存格，如果為合併儲存格則強迫畫外框，如果為單一儲存格則偵測是否上下左右邊界有無畫線，有畫線則有外框。 Private MyACAD As New clsACAD Const TXT_COE = 0.8 Const ROW_COE = 0.335 Const COL_COE = 2.1 Public lupt As Variant Private rng_start As Range Private rng_end As Range Private rng_first As Range Sub ExportToCAD() For Each rng In Selection ...
Read more »